[haskell_edsl] Add examples

Author: jbransen

haskell_edsl/README.md

@@ -40,3 +40,15 @@ The tests can be run with:
 ```
 cabal test
 ```
+
+## Building the examples and other checker programs
+
+Install the library globally on your system with:
+```
+cabal install
+```
+
+Then a checker program can be build with:
+```
+ghc --make ProgramName.hs
+```

haskell_edsl/examples/ArrangingHat.hs

@@ -0,0 +1,17 @@
+-- NWERC 2016 - Arranging Hat
+-- See http://2016.nwerc.eu
+
+module Main where
+
+import Control.Monad
+import Checktestdata
+
+main :: IO ()
+main = ctdMain $ do
+  n <- int 1 40
+  space
+  m <- int 1 400
+  newline
+  replicateM_ (fromIntegral n) $ do
+    replicateM_ (fromIntegral m) $ regex "[0-9]"
+    newline

haskell_edsl/examples/CarefulAscent.hs

@@ -0,0 +1,34 @@
+-- NWERC 2016 - Careful Ascent
+-- See http://2016.nwerc.eu
+
+{-# OPTIONS_GHC -fno-warn-type-defaults #-}
+module Main where
+
+import Control.Monad
+import Checktestdata
+
+main :: IO ()
+main = ctdMain $ do
+  x <- int (-(10^7)) (10^7)
+  space
+  y <- int (max 1 (abs x)) (10^8)
+  newline
+
+  n <- int 0 100
+  newline
+
+  shields <- forM [1..n] $ \i -> do
+    li <- int 0 y
+    space
+    ui <- int (li+1) y
+    space
+    fi <- floatP 0.1 10.0 0 10
+    newline
+    return (i,li,ui,fi)
+
+  -- Check for each pair that they don't intersect
+  assert $ and $
+    [ i == j || ui <= lj || uj <= li
+    | (i,li,ui,_) <- shields
+    , (j,lj,uj,_) <- shields
+    ]

haskell_edsl/examples/FreeWeights.hs

@@ -0,0 +1,33 @@
+-- NWERC 2016 - Free Weights
+-- See http://2016.nwerc.eu
+
+{-# OPTIONS_GHC -fno-warn-type-defaults #-}
+module Main where
+
+import Control.Monad
+import Checktestdata
+import Data.List
+
+main :: IO ()
+main = ctdMain $ do
+  n <- int 1 (10^6)
+  newline
+
+  row1 <- repSep n space $ int 1 (10^9)
+  newline
+  row2 <- repSep n space $ int 1 (10^9)
+  newline
+
+  -- Check that each number appears exactly twice.
+  -- Numbers at odd positions should be equal to
+  -- the next number in the list, and numbers at
+  -- even positions should be smaller than the next.
+  let ws = sort $ row1 ++ row2
+  let check (i,v,w) | odd i     = v == w
+                    | otherwise = v < w
+  assert $ all check $ zip3 [1..] ws (tail ws)
+
+-- | Replicate the given script n times, separated by
+--   something else.
+repSep :: Integer -> CTD () -> CTD a -> CTD [a]
+repSep n sep a = forM [1..n] $ \i -> when (i > 1) sep >> a

haskell_edsl/examples/Interception.hs

@@ -0,0 +1,36 @@
+-- NCPC 2016 - Interception
+-- See https://ncpc.idi.ntnu.no/ncpc2016/
+
+import Checktestdata
+import Control.Monad
+
+main :: IO ()
+main = ctdMain $ do
+  n <- int 4 250000
+  space
+  m <- int 1 500000
+  space
+  c1 <- int 1 (n-1)
+  space
+  c2 <- int 1 (n-1)
+  newline
+
+  assert $ n `mod` 2 == 0
+  assert $ c1 `mod` 2 == 1
+  assert $ c2 `mod` 2 == 1
+  assert $ c1 < c2
+
+  ab <- replicateM (fromInteger m) $ do
+    ai <- int 1 n
+    space
+    bi <- int 1 n
+    assert $ ai /= bi
+    if (ai `mod` 2 /= bi `mod` 2) then do
+      space
+      c <- int 1 n
+      newline
+      assert $ c == c1 || c == c2
+    else newline
+    return $ if ai > bi then (bi, ai) else (ai, bi)
+
+  assert $ unique ab