build.gradle

plugins {
    id 'org.springframework.boot' version '3.4.3' apply false
    id 'io.spring.dependency-management' version '1.1.7' apply false
    id 'checkstyle'
}

allprojects {
    group = 'co.kr.pinhouse'
    version = '0.0.1-SNAPSHOT'

    repositories {
        mavenCentral()
    }
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'checkstyle'

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
        }
    }

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    dependencies {
        // 모든 모듈 공통 의존성
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        // 테스트 공통
        testImplementation 'org.springframework.boot:spring-boot-starter-test'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    }

    tasks.named('test') {
        useJUnitPlatform()
    }

    // 기본적으로 모든 모듈은 plain jar 생성 (실행 불가)
    tasks.named('bootJar') {
        enabled = false
    }

    tasks.named('jar') {
        enabled = true
    }

    checkstyle {
        maxWarnings = 0 // 경고가 1개라도 있으면 실패하게 설정
        configFile = rootProject.file("checkstyle/naver-checkstyle-rules.xml")
        configProperties = ["suppressionFile": rootProject.file("checkstyle/naver-checkstyle-suppressions.xml").absolutePath]
        toolVersion = "13.0.0"
    }

    tasks.withType(org.gradle.api.plugins.quality.Checkstyle).configureEach {
        reports {
            xml.required = true
            html.required = true
        }
    }
}

// module-app 모듈만 실행 가능한 bootJar 생성
project(':module-app') {
    tasks.named('bootJar') {
        enabled = true
    }

    tasks.named('jar') {
        enabled = false
    }
}