Add NixOS package (#257)

Closes #106

Author: emmanuelrosa

default.nix

@@ -0,0 +1,8 @@
+# The following Nix expression provides the result of building the tiddlydesktop.nix package.
+# The version of Nixpkgs comes from the Nix Flake lock file, flake.lock.
+# To build, simply change to the repo's directory and run: nix-build
+
+let
+  lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+  pkgs = import (fetchTarball "https://github.com/NixOS/nixpkgs/archive/${lock.nodes.nixpkgs.locked.rev}.tar.gz") { };
+in pkgs.callPackage ./tiddlydesktop.nix { }

flake.lock

@@ -0,0 +1,25 @@
+# This is a Nix Flake which provides the tiddlydesktop package.
+# To execute TiddlyDesktop, simply run: nix run github:TiddlyWiki/TiddlyDesktop
+
+{
+  description = "A Nix Flake for TiddlyDesktop.";
+
+  outputs = { self, nixpkgs }: {
+
+    packages.x86_64-linux.tiddlydesktop = let 
+      pkgs = import "${nixpkgs}" {
+        system = "x86_64-linux";
+      };
+    in pkgs.callPackage ./tiddlydesktop.nix { };
+
+    packages.x86_64-linux.default = self.packages.x86_64-linux.tiddlydesktop;
+    
+    apps.x86_64-linux.tiddlydesktop = {
+      type = "app";
+      program = "${self.packages.x86_64-linux.tiddlydesktop}/bin/tiddlydesktop";
+    };
+
+    apps.x86_64-linux.default = self.apps.x86_64-linux.tiddlydesktop;
+
+  };
+}

flake.nix

@@ -20,6 +20,32 @@ Unzip into a folder and run `TiddlyWiki.app` or `nw.exe` and for linux `nw`
 
 Note that TiddlyDesktop will not work correctly from a Windows UNC network share (eg ``\\MY-SERVER\SHARE\MyFolder``). You should map the network share to a local drive, and run it from there.
 
+## NixOS
+
+To install TiddlyDesktop on NixOS, you first need to add this repo to your `configuration.nix`; Using a `let` expression at the top of the file is a good approach: 
+
+```
+let
+  twdesktop = let
+    rev = "Set this to the TiddlyDesktop Git revision that you want to install.";
+  in import (fetchTarball "https://github.com/TiddlyWiki/TiddlyDesktop/archive/${rev}.tar.gz") { };
+in
+ ...
+``` 
+
+Then add the attribute name (which is twdesktop in the example above) to your `systemPackages`:
+
+```
+...
+environment.systemPackages = with pkgs; [
+   ...
+   twdesktop
+];
+...
+```
+
+In addition to the method described above, the tiddlydesktop package is available as a Nix Flake; See https://nixos.wiki/wiki/Flakes to read more about Flakes. Simply use the Flake input `github:TiddlyWiki/TiddlyDesktop`. For example, you can run TiddlyDesktop with the command `nix run github:TiddlyWiki/TiddlyDesktop`.
+
 # Usage
 
 ## Multiple Configurations

readme.md

@@ -0,0 +1,80 @@
+{ stdenv
+, lib
+, nodePackages
+, nwjs
+, jq
+, writeScript
+, bash
+, makeDesktopItem
+, copyDesktopItems
+, gsettings-desktop-schemas
+, wrapGAppsHook
+, gtk3
+}:
+let
+  launcher = writeScript "tiddlydesktop" ''
+    #! ${bash}/bin/bash
+
+    ${nwjs}/bin/nw @out@/lib/tiddlydesktop $@
+  '';
+
+  packageJson = builtins.fromJSON (builtins.readFile ./package.json);
+in stdenv.mkDerivation rec {
+  pname = "tiddlydesktop";
+  version = "${packageJson.version}";
+
+  src = ./.;
+
+  nativeBuildInputs = [ copyDesktopItems wrapGAppsHook gtk3 ]; 
+  buildInputs = [ nodePackages.tiddlywiki jq ];
+
+  # These instructions are based on those from the bld.sh upstream script.
+  buildPhase = ''
+    cp -RH ${nodePackages.tiddlywiki}/lib/node_modules/tiddlywiki source/tiddlywiki
+    chmod -R u+w source
+    cp -RH plugins/tiddlydesktop source/tiddlywiki/plugins/tiddlywiki
+
+    version=$(jq < package.json '.version')
+    plugin_info=$(mktemp) 
+    cat source/tiddlywiki/plugins/tiddlywiki/tiddlydesktop/plugin.info > $plugin_info
+    jq < $plugin_info --arg version $version '. + {version: $version}' > source/tiddlywiki/plugins/tiddlywiki/tiddlydesktop/plugin.info
+    echo $version > source/tiddlywiki/plugins/tiddlywiki/tiddlydesktop/system/version.txt
+  '';
+ 
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    mkdir -p $out/lib/tiddlydesktop
+    mkdir -p $out/share/icons/hicolor
+
+    cp -R source/* $out/lib/tiddlydesktop/
+    cp ${launcher} $out/bin/tiddlydesktop
+    substituteAllInPlace $out/bin/tiddlydesktop
+
+    for n in 16 32 48 64 128 256 1024; do
+      size=$n"x"$n
+      mkdir -p $out/share/icons/hicolor/$size/apps
+      cp icons/app-icon$n.png $out/share/icons/hicolor/$size/apps/${pname}.png
+    done
+
+    runHook postInstall
+  ''; 
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = pname;
+      exec = pname;
+      icon = pname;
+      desktopName = "Tiddly Desktop";
+      categories = ["Utility" "TextEditor"];
+    })
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/TiddlyWiki/TiddlyDesktop";
+    description = "A custom desktop browser for TiddlyWiki 5 and TiddlyWiki Classic, based on nw.js";
+    license = licenses.bsd0;
+    maintainers = with maintainers; [ emmanuelrosa ];
+    platforms = [ "x86_64-linux" ];
+  };
+}