parse select inputs that have no name #2 (#40)

In order to do this, I had to allow find_input to find inputs that have
no name. Before, we treated an undef in the name (actually, the
'selector') as an instruction not to match the name. To put option
elements into the correct surrounding select, we have to match them by
their name, including when there is no name.

Two of the tests I have added don't produce what I would expect. I think
this is another bug. It seems we include unnamed fields that have a
value in the query string, as long as they have a name attribute. This
leads to query strings such as 'name=value&=value'. The W3 specification
explicitly says that only element that have names should be submitted,
so I believe this behaviour is wrong.

Author: simbabque

Changes

@@ -4,6 +4,10 @@ Change history for HTML-Form
     - Use "croak" instead of "die" to show errors from the perspective of the
       caller [RT#20499] (GH#29) (Julien Fiegehenn)
     - Remove the executable bit from a couple of tests (GH#41) (James Raspass)
+    - <option>s within select fields without a name no longer get merged into
+      the previous select field (GH#2) (Julien Fiegehenn)
+    - find_input() can now take a reference to undef to explicitly find inputs
+      that have no name (GH#2) (Julien Fiegehenn)
 
 6.09      2022-08-14 22:16:37Z
 

lib/HTML/Form.pm

@@ -488,24 +488,35 @@ This method is used to locate specific inputs within the form.  All
 inputs that match the arguments given are returned.  In scalar context
 only the first is returned, or C<undef> if none match.
 
-If $selector is not C<undef>, then the input's name, id, class attribute must
-match.  A selector prefixed with '#' must match the id attribute of the input.
-A selector prefixed with '.' matches the class attribute.  A selector prefixed
-with '^' or with no prefix matches the name attribute.
+If C<$selector> is not C<undef>, then the input's I<name>, I<id> or I<class>
+attribute must match.
+A selector prefixed with '#' must match the I<id> attribute of the input.
+A selector prefixed with '.' matches the I<class> attribute. A selector prefixed
+with '^' or with no prefix matches the I<name> attribute.
 
-If $type is not C<undef>, then the input must have the specified type.
+    my @by_id         = $form->find_input( '#some-id' );
+    my @by_class      = $form->find_input( '.some-class' );
+    my @by_name       = $form->find_input( '^some-name' );
+    my @also_by_name  = $form->find_input( 'some-name' );
+
+If you want to find an input that has no I<name> at all, pass in a reference
+to C<undef>.
+
+    my @nameless_inputs = $form->find_input( \undef );
+
+If C<$type> is not C<undef>, then the input must have the specified type.
 The following type names are used: "text", "password", "hidden",
 "textarea", "file", "image", "submit", "radio", "checkbox" and "option".
 
-The $index is the sequence number of the input matched where 1 is the
-first.  If combined with $name and/or $type, then it selects the I<n>th
-input with the given name and/or type.
+The C<$index> is the sequence number of the input matched where 1 is the
+first.  If combined with C<$selector> and/or C<$type>, then it selects the
+I<n>th input with the given I<name> and/or type.
 
 =cut
 
 sub find_input
 {
-    my($self, $name, $type, $no) = @_;
+    my($self, $selector, $type, $no) = @_;
     Carp::croak "Invalid index $no"
         if defined $no && $no < 1;
     if (wantarray) {
@@ -514,7 +525,20 @@ sub find_input
 	my @res;
 	my $c;
 	for (@{$self->{'inputs'}}) {
-	    next if defined($name) && !$_->selected($name);
+        if ( defined($selector) ) {
+
+            # an input that explicitly has no name
+            if ( ref($selector) eq 'SCALAR' ) {
+                next
+                  if !defined($$selector) && $_->{name};
+            }
+
+            # an input that does not fit this selector
+            else {
+                next
+                  if !$_->selected($selector);
+            }
+        }
 	    next if $type && $type ne $_->{type};
 	    $c++;
 	    next if $no && $no != $c;
@@ -526,7 +550,20 @@ sub find_input
     else {
 	$no ||= 1;
 	for (@{$self->{'inputs'}}) {
-	    next if defined($name) && !$_->selected($name);
+        if ( defined($selector) ) {
+
+            # an input that explicitly has no name
+            if ( ref($selector) eq 'SCALAR' ) {
+                next
+                  if !defined($$selector) && $_->{name};
+            }
+
+            # an input that does not fit this selector
+            else {
+                next
+                  if !$_->selected($selector);
+            }
+        }
 	    next if $type && $type ne $_->{type};
 	    next if --$no;
 	    return $_;
@@ -1235,7 +1272,9 @@ sub add_to_form
     my $m = $self->{menu}[0];
     $m->{disabled}++ if delete $self->{option_disabled};
 
-    my $prev = $form->find_input($self->{name}, $self->{type}, $self->{idx});
+    # if there was no name we have to search for an input that explicitly has
+    # no name either, because otherwise the name attribute would be ignored
+    my $prev = $form->find_input($self->{name} || \undef, $self->{type}, $self->{idx});
     return $self->SUPER::add_to_form($form) unless $prev;
 
     # merge menus

t/form.t

@@ -3,7 +3,7 @@
 use strict;
 use warnings;
 
-use Test::More tests => 129;
+use Test::More;
 use HTML::Form;
 
 my @warn;
@@ -623,3 +623,52 @@ Content-Type: application/x-www-form-urlencoded
 
 submit=
 EOT
+
+# select with a name followed by select without a name GH#2
+$f = HTML::Form->parse(<<EOT, "http://localhost/");
+<form action="target.html" method="get">
+<select>
+<option selected>option in unnamed before</option>
+</select>
+<select name="foo">
+<option selected>option in named</option>
+</select>
+<select>
+<option selected>option in unnamed after 1</option>
+</select>
+<select name="">
+<option selected>option in empty string name</option>
+</select>
+EOT
+
+TODO: {
+  local $TODO = 'input with empty name should not be included';
+  is(
+      join( "|", $f->form ),
+      "foo|option in named",
+      "options in unnamed selects are ignored"
+  );
+}
+
+# explicitly selecting an input that has no name
+my @nameless_inputs = $f->find_input( \undef );
+is( scalar @nameless_inputs,
+    3, 'find_input with ref to undef finds three forms' );
+ok(
+    ( !grep { $_->{name} } @nameless_inputs ),
+    '... and none of them has a name'
+);
+
+ok(
+    !( scalar $f->find_input( \undef ) )->{name},
+    'find_input with ref to undef in scalar context'
+);
+TODO: {
+  local $TODO = 'input with empty name should not be included';
+  is($f->click->as_string, <<"EOT");
+GET http://localhost/target.html?foo=option+in+named
+
+EOT
+}
+
+done_testing;