Improve arity handling

Author: weavejester

src/ring/util/codec.clj

@@ -31,10 +31,12 @@
 (defn percent-encode
   "Percent-encode every character in the given string using either the specified
   encoding, or UTF-8 by default."
-  [^String unencoded & [^String encoding]]
-  (->> (.getBytes unencoded (or encoding "UTF-8"))
-       (map (partial format "%%%02X"))
-       (str/join)))
+  ([unencoded]
+   (percent-encode unencoded "UTF-8"))
+  ([^String unencoded ^String encoding]
+   (->> (.getBytes unencoded encoding)
+        (map (partial format "%%%02X"))
+        (str/join))))
 
 (defn- parse-bytes [encoded-bytes]
   (->> (re-seq #"%[A-Za-z0-9]{2}" encoded-bytes)
@@ -45,28 +47,34 @@
 (defn percent-decode
   "Decode every percent-encoded character in the given string using the
   specified encoding, or UTF-8 by default."
-  [^String encoded & [^String encoding]]
-  (str/replace encoded
-               #"(?:%[A-Za-z0-9]{2})+"
-               (fn [chars]
-                 (-> ^bytes (parse-bytes chars)
-                     (String. (or encoding "UTF-8"))
-                     (fix-string-replace-bug)))))
+  ([encoded]
+   (percent-decode encoded "UTF-8"))
+  ([^String encoded ^String encoding]
+   (str/replace encoded
+                #"(?:%[A-Za-z0-9]{2})+"
+                (fn [chars]
+                  (-> ^bytes (parse-bytes chars)
+                      (String. encoding)
+                      (fix-string-replace-bug))))))
 
 (defn url-encode
   "Returns the url-encoded version of the given string, using either a specified
   encoding or UTF-8 by default."
-  [unencoded & [encoding]]
-  (str/replace
+  ([unencoded]
+   (url-encode unencoded "UTF-8"))
+  ([unencoded encoding]
+   (str/replace
     unencoded
     #"[^A-Za-z0-9_~.+-]+"
-    #(double-escape (percent-encode % encoding))))
+    #(double-escape (percent-encode % encoding)))))
 
 (defn ^String url-decode
   "Returns the url-decoded version of the given string, using either a specified
   encoding or UTF-8 by default. If the encoding is invalid, nil is returned."
-  [encoded & [encoding]]
-  (percent-decode encoded encoding))
+  ([encoded]
+   (url-decode encoded "UTF-8"))
+  ([encoded encoding]
+   (percent-decode encoded encoding)))
 
 (defn base64-encode
   "Encode an array of bytes into a base64 encoded string."
@@ -106,28 +114,34 @@
   "Encode the supplied value into www-form-urlencoded format, often used in
   URL query strings and POST request bodies, using the specified encoding.
   If the encoding is not specified, it defaults to UTF-8"
-  [x & [encoding]]
-  (form-encode* x (or encoding "UTF-8")))
+  ([x]
+   (form-encode x "UTF-8"))
+  ([x encoding]
+   (form-encode* x encoding)))
 
 (defn form-decode-str
   "Decode the supplied www-form-urlencoded string using the specified encoding,
   or UTF-8 by default."
-  [^String encoded & [encoding]]
-  (try
-    (URLDecoder/decode encoded (or encoding "UTF-8"))
-    (catch Exception _ nil)))
+  ([encoded]
+   (form-decode-str encoded "UTF-8"))
+  ([^String encoded encoding]
+   (try
+     (URLDecoder/decode encoded encoding)
+     (catch Exception _ nil))))
 
 (defn form-decode
   "Decode the supplied www-form-urlencoded string using the specified encoding,
   or UTF-8 by default. If the encoded value is a string, a string is returned.
   If the encoded value is a map of parameters, a map is returned."
-  [^String encoded & [encoding]]
-  (if-not (.contains encoded "=")
-    (form-decode-str encoded encoding)
-    (reduce
-     (fn [m param]
-       (if-let [[k v] (str/split param #"=" 2)]
-         (assoc-conj m (form-decode-str k encoding) (form-decode-str v encoding))
-         m))
-     {}
-     (str/split encoded #"&"))))
+  ([encoded]
+   (form-decode encoded "UTF-8"))
+  ([^String encoded encoding]
+   (if-not (.contains encoded "=")
+     (form-decode-str encoded encoding)
+     (reduce
+      (fn [m param]
+        (if-let [[k v] (str/split param #"=" 2)]
+          (assoc-conj m (form-decode-str k encoding) (form-decode-str v encoding))
+          m))
+      {}
+      (str/split encoded #"&")))))