Add async support to wrap-forwarded-remote-addr

Author: weavejester

src/ring/middleware/proxy_headers.clj

@@ -2,12 +2,21 @@
   "Middleware for handling headers set by HTTP proxies."
   (:require [clojure.string :as str]))
 
+(defn forwarded-remote-addr-request
+  "Change the :remote-addr key of the request map to the last value present in
+  the X-Forwarded-For header. See: wrap-forwarded-remote-addr."
+  [request]
+  (if-let [forwarded-for (get-in request [:headers "x-forwarded-for"])]
+    (let [remote-addr (str/trim (re-find #"[^,]*$" forwarded-for))]
+      (assoc request :remote-addr remote-addr))
+    request))
+
 (defn wrap-forwarded-remote-addr
   "Middleware that changes the :remote-addr of the request map to the
   last value present in the X-Forwarded-For header."
   [handler]
-  (fn [request]
-    (if-let [forwarded-for (get-in request [:headers "x-forwarded-for"])]
-      (let [remote-addr (str/trim (re-find #"[^,]*$" forwarded-for))]
-        (handler (assoc request :remote-addr remote-addr)))
-      (handler request))))
+  (fn
+    ([request]
+     (handler (forwarded-remote-addr-request request)))
+    ([request respond raise]
+     (handler (forwarded-remote-addr-request request) respond raise))))

test/ring/middleware/proxy_headers_test.clj

@@ -24,3 +24,24 @@
                      (header "x-forwarded-for" "10.0.1.9, 192.168.4.98, 1.2.3.4"))
             resp (handler req)]
         (is (= (:body resp) "1.2.3.4"))))))
+
+(deftest test-wrap-forwarded-remote-addr-cps
+  (let [handler (wrap-forwarded-remote-addr
+                 (fn [request respond _] (respond (response (:remote-addr request)))))]
+    (testing "without x-forwarded-for"
+      (let [req  (assoc (request :get "/") :remote-addr "1.2.3.4")
+            resp (promise)
+            ex   (promise)]
+        (handler req resp ex)
+        (is (not (realized? ex)))
+        (is (= (:body @resp) "1.2.3.4"))))
+
+    (testing "with x-forwarded-for"
+      (let [req  (-> (request :get "/")
+                     (assoc :remote-addr "127.0.0.1")
+                     (header "x-forwarded-for" "1.2.3.4"))
+            resp (promise)
+            ex   (promise)]
+        (handler req resp ex)
+        (is (not (realized? ex)))
+        (is (= (:body @resp) "1.2.3.4"))))))