spring-security/build.gradle at main · spring-projects/spring-security · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
import io.spring.gradle.IncludeRepoTask
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import trang.RncToXsd
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

buildscript {
	dependencies {
		classpath libs.io.spring.javaformat.spring.javaformat.gradle.plugin
		classpath libs.io.spring.nohttp.nohttp.gradle
		classpath libs.io.freefair.gradle.aspectj.plugin
		classpath libs.org.jetbrains.kotlin.kotlin.gradle.plugin
		classpath libs.com.netflix.nebula.nebula.project.plugin
	}
	repositories {
		maven { url='https://plugins.gradle.org/m2/' }
	}
}

plugins {
	alias(libs.plugins.org.gradle.wrapper.upgrade)
}

apply plugin: 'io.spring.nohttp'
apply plugin: 'locks'
apply plugin: 'io.spring.convention.root'
apply plugin: 'org.jetbrains.kotlin.jvm'
apply plugin: 'org.springframework.security.versions.verify-dependencies-versions'
apply plugin: 'org.springframework.security.check-expected-branch-version'
apply plugin: 'io.spring.security.release'

group = 'org.springframework.security'
description = 'Spring Security'

ext.snapshotBuild = version.contains("SNAPSHOT")
ext.releaseBuild = version.contains("SNAPSHOT")
ext.milestoneBuild = !(snapshotBuild || releaseBuild)

repositories {
	mavenCentral()
	maven { url = "https://repo.spring.io/milestone" }
}

springRelease {
	weekOfMonth = 3
	dayOfWeek = 1
	referenceDocUrl = "https://docs.spring.io/spring-security/reference/{version}/index.html"
	apiDocUrl = "https://docs.spring.io/spring-security/reference/{version}/api/java/index.html"
	replaceSnapshotVersionInReferenceDocUrl = true
}

allprojects {
	if (!['spring-security-bom', 'spring-security-docs'].contains(project.name)) {
		apply plugin: 'io.spring.javaformat'
		apply plugin: 'checkstyle'

		pluginManager.withPlugin("io.spring.convention.checkstyle") {
			dependencies {
				checkstyle libs.io.spring.javaformat.spring.javaformat.checkstyle
			}
			checkstyle {
				toolVersion = '8.34'
			}
		}

		if (project.name.contains('sample')) {
			tasks.whenTaskAdded { task ->
				if (task.name.contains('format') || task.name.contains('checkFormat') || task.name.contains("checkstyle")) {
					task.enabled = false
				}
			}
		}
	}
}

develocity {
	buildScan {
		termsOfUseUrl = 'https://gradle.com/help/legal-terms-of-use'
		termsOfUseAgree = 'yes'
	}
}

nohttp {
	source.exclude "buildSrc/build/**", "**/build/**", "**/target/**", "javascript/.gradle/**", "javascript/package-lock.json", "javascript/node_modules/**", "javascript/build/**", "javascript/dist/**"
	source.builtBy(project(':spring-security-config').tasks.withType(RncToXsd))
}

tasks.named('checkstyleNohttp') {
	maxHeapSize = '1g'
}

tasks.register('cloneRepository', IncludeRepoTask) {
	repository = project.getProperties().get("repositoryName")
	ref = project.getProperties().get("ref")
	var defaultDirectory = project.file("build/tmp/clone")
	outputDirectory = project.hasProperty("cloneOutputDirectory") ? project.file("$cloneOutputDirectory") : defaultDirectory
}

wrapperUpgrade {
	gradle {
		'spring-security' {
			repo = 'spring-projects/spring-security'
			baseBranch = '6.3.x' // runs only on 6.3.x and the update is merged forward to main
		}
	}
}