Skip to content

LODSPeaKr

Jump to bottom
timrdf edited this page Jan 29, 2012 · 65 revisions

Alvaro Graves has a simple Linked Data publishing kit

This page has my DataFAQs-specific notes about lodspeakr. I'm putting the more general stuff onto his wiki directly. I've forked Alvaro's lodspeakr at https://github.com/timrdf/DataFAQs-lodspeakr to contain datafaqs-specific models and views. The plan it to always merge his latest into mine, with the only difference being my models and views.

Pieces of DataFAQs' lodspeakr

Notes

When loading http://sparql.tw.rpi.edu/datafaqs/epoch, show:

  • A list of epochs (the number of faqts used, and the number of datasets evaluated)

When loading http://sparql.tw.rpi.edu/datafaqs/epoch/2012-01-21, show:

  • The three configuration graphs (datasets, faqt-services, dataset-references) with dump links.
  • The faqt service description graphs (with triple count and dump links)
  • The dataset description graphs (with triple count and dump links)
  • The evaluation description graphs (with triple count and dump links).
    • % passed instances in evaluation

Queries

Configuration Graphs for a given epoch (fill in ?epoch). These graphs list the FAqT evaluation services to apply, the Datasets to evaluate, and references from which to obtain additional dataset descriptions.

prefix void:     <http://rdfs.org/ns/void#>
prefix sd:       <http://www.w3.org/ns/sparql-service-description#>
prefix datafaqs: <http://purl.org/twc/vocab/datafaqs#>

select distinct ?gn ?epoch ?config ?triples ?name ?dump
where { 
   graph ?gn {

      ?epoch a datafaqs:Epoch; 
         void:subset ?config 
      .
      ?config a datafaqs:EpochConfigurationGraph .

      optional {             ?config  void:triples  ?triples }
      optional {             ?config  void:dataDump ?dump    }
      optional { [] sd:graph ?config; sd:name       ?name    }
   }
} order by desc(?config) ?gn ?epoch ?config

FAqT self-descriptions provided during a given epoch (fill in ?epoch):

prefix void:     <http://rdfs.org/ns/void#>
prefix sd:       <http://www.w3.org/ns/sparql-service-description#>
prefix prov:     <http://www.w3.org/ns/prov-o/>
prefix datafaqs: <http://purl.org/twc/vocab/datafaqs#>

select distinct ?autobio ?triples ?name ?dump
where { 
   graph ?gn {

      ?epoch  a datafaqs:Epoch; 
         void:subset ?autobio 
      .
      ?autobio a prov:Account; 
         prov:wasAttributedTo ?service; # The service was 
         foaf:primaryTopic    ?service  # talking about itself.
      .
      ?service a datafaqs:FAqTService .

      optional {             ?autobio  void:dataDump ?dump    }
      optional {             ?autobio  void:triples  ?triples }
      optional { [] sd:graph ?autobio; sd:name       ?name    }
   }
}

PREFIX conversion: <http://purl.org/twc/vocab/conversion/>
PREFIX datafaqs: <http://purl.org/twc/vocab/datafaqs#>
PREFIX prov: <http://www.w3.org/ns/prov-o/>
SELECT distinct ?s ?a
WHERE {
  GRAPH ?gn  {
 ?s prov:specializationOf ?a
  }
}order by ?s

PREFIX conversion: <http://purl.org/twc/vocab/conversion/>
PREFIX datafaqs: <http://purl.org/twc/vocab/datafaqs#>
PREFIX prov: <http://www.w3.org/ns/prov-o/>
SELECT distinct ?ephemeral ?type
WHERE {
  GRAPH ?gn  {
    ?ephemeral prov:specializationOf <http://thedatahub.org/dataset/morelab>.
  }
  GRAPH ?ephemeral {
    <http://thedatahub.org/dataset/morelab> a ?type
  }
  filter(?type!=datafaqs:EvaluatedDataset)
}

list the faqts and the size of the self-describing graphs across epochs.

list the datasets and the size of the description graphs across epochs.

Data dumps for the graphs in the endpoint:

PREFIX void: <http://rdfs.org/ns/void#>
PREFIX sd:   <http://www.w3.org/ns/sparql-service-description#>
SELECT distinct ?name ?dump
WHERE {
  GRAPH ?gn {
     [] sd:name ?name;
        sd:graph [ void:dataDump ?dump ] .
  }
}

PREFIX prov: <http://www.w3.org/ns/prov-o/>
PREFIX void: <http://rdfs.org/ns/void#>
PREFIX datafaqs: <http://purl.org/twc/vocab/datafaqs#>

SELECT distinct ?gn ?ephemeral ?dataset
WHERE {
  GRAPH <http://datafaqs.tw.rpi.edu/datafaqs/epoch/2012-01-27/config/datasets> {
    ?dataset a datafaqs:CKANDataset
  }
  GRAPH ?gn {
    ?ephemeral prov:specializationOf ?dataset
  }
}

PREFIX void:     <http://rdfs.org/ns/void#>
PREFIX sd:       <http://www.w3.org/ns/sparql-service-description#>
PREFIX datafaqs: <http://purl.org/twc/vocab/datafaqs#>

SELECT ?name ?type count(?s)
WHERE {
   GRAPH ?name {
      ?s a ?type
   }
} GROUP BY ?name ?type

PREFIX void:     <http://rdfs.org/ns/void#>
PREFIX sd:       <http://www.w3.org/ns/sparql-service-description#>
PREFIX datafaqs: <http://purl.org/twc/vocab/datafaqs#>

SELECT distinct ?s
WHERE {
   GRAPH <http://datafaqs.tw.rpi.edu/datafaqs/epoch/2012-01-29/dataset/4> {
      ?s ?p []
   }
}

PREFIX void:     <http://rdfs.org/ns/void#>
PREFIX sd:       <http://www.w3.org/ns/sparql-service-description#>
PREFIX datafaqs: <http://purl.org/twc/vocab/datafaqs#>
PREFIX prov:     <http://www.w3.org/ns/prov-o/>
PREFIX dcterms:  <http://purl.org/dc/terms/> 

SELECT distinct ?faqt_service (count(?ephemeral) as ?num_epochs)
WHERE {
   GRAPH ?name {
      ?ephemeral a datafaqs:FAqTService; prov:specializationOf ?faqt_service ; dcterms:date ?date .
   }
}GROUP BY ?faqt_service

Dataset evaluations, their sizes, and their dump files for a given epoch:

PREFIX void:     <http://rdfs.org/ns/void#>
PREFIX sd:       <http://www.w3.org/ns/sparql-service-description#>
PREFIX datafaqs: <http://purl.org/twc/vocab/datafaqs#>
PREFIX prov:     <http://www.w3.org/ns/prov-o/>
PREFIX dcterms:  <http://purl.org/dc/terms/> 
PREFIX foaf:     <http://xmlns.com/foaf/0.1/>

SELECT distinct ?dataset ?triples ?dump
WHERE {
   GRAPH ?gn {
      {{epoch}} void:subset ?abstract .
      []
         a sd:NamedGraph;
         sd:name  ?name;
         sd:graph ?abstract
      .
      ?abstract
         a prov:Account, sd:Graph, void:Graph, datafaqs:Evaluation;
         void:triples         ?triples;
         prov:wasAttributedTo ?faqt_service;
         foaf:primaryTopic    ?ephemeral;
         void:dataDump        ?dump
      .
      ?ephemeral 
         a void:Dataset;
         prov:specializationOf ?dataset
      .
   }
}

prefix void:     <http://rdfs.org/ns/void#>
prefix datafaqs: <http://purl.org/twc/vocab/datafaqs#>

select distinct ?g ?s ?subset
where { 
   graph ?gn {
      ?s a datafaqs:Epoch ; void:subset ?subset
   }
} order by ?subset ?s ?g

Clone this wiki locally