infra: deploy postgres primary and monitor

Author: JuArce

infra/aggregation_mode/terraform/cloudinit/scaleway-cloud-init.yaml

@@ -0,0 +1,38 @@
+#cloud-config
+hostname: ${hostname}
+fqdn: ${hostname}
+manage_etc_hosts: true
+
+users:
+  - name: app
+    shell: /bin/bash
+    ssh_authorized_keys:
+      - ${ssh_public_key}
+  - name: admin
+    shell: /bin/bash
+    sudo: ALL=(ALL) NOPASSWD:ALL
+    ssh_authorized_keys:
+      - ${ssh_public_key}
+
+package_update: true
+package_upgrade: true
+
+packages:
+  - ca-certificates
+  - curl
+  - wget
+  - gnupg
+  - vim
+  - git
+  - zip
+  - unzip
+  - openssl
+  - libssl-dev
+  - build-essential
+  - rsyslog
+  - htop
+  - rsync
+  - pkg-config
+
+runcmd:
+  - loginctl enable-linger app

infra/aggregation_mode/terraform/main.tf

@@ -0,0 +1,12 @@
+provider "aws" {
+  region = "us-east-2"
+}
+
+
+module "postgres_monitor" {
+  source = "./postgres_monitor"
+}
+
+module "postgres_primary" {
+  source = "./postgres_primary"
+}

infra/aggregation_mode/terraform/output.tf

@@ -0,0 +1,9 @@
+output "postgres_monitor_instance_hostname" {
+  description = "Private DNS name of the EC2 instance."
+  value       = module.postgres_monitor.instance_hostname
+}
+
+output "postgres_monitor_public_ip" {
+  description = "Public IP address of the EC2 instance."
+  value       = module.postgres_monitor.public_ip
+}

infra/aggregation_mode/terraform/postgres_monitor/main.tf

@@ -0,0 +1,74 @@
+# Upload existing SSH public key to AWS
+resource "aws_key_pair" "ssh_key" {
+  key_name   = var.ssh_key_name
+  public_key = file(var.ssh_public_key_path)
+}
+
+# Debian 12
+data "aws_ami" "debian12" {
+  most_recent = true
+
+  filter {
+    name   = "name"
+    values = ["debian-12-amd64-*"]
+  }
+
+  filter {
+    name   = "virtualization-type"
+    values = ["hvm"]
+  }
+
+  filter {
+    name   = "root-device-type"
+    values = ["ebs"]
+  }
+
+  owners = ["136693071363"] # https://wiki.debian.org/Cloud/AmazonEC2Image/
+}
+
+resource "aws_security_group" "ssh_access" {
+  name        = "postgres-monitor-ssh-access"
+  description = "Allow SSH inbound traffic for postgres monitor"
+
+  ingress {
+    description = "SSH from anywhere"
+    from_port   = 22
+    to_port     = 22
+    protocol    = "tcp"
+    cidr_blocks = ["0.0.0.0/0"]
+  }
+
+  egress {
+    description = "Allow all outbound traffic"
+    from_port   = 0
+    to_port     = 0
+    protocol    = "-1"
+    cidr_blocks = ["0.0.0.0/0"]
+  }
+
+  tags = {
+    Name = "postgres-monitor-ssh-access"
+  }
+}
+
+resource "aws_instance" "postgres_monitor" {
+  ami           = data.aws_ami.debian12.id
+  instance_type = var.instance_type
+  key_name      = var.ssh_key_name
+  vpc_security_group_ids = [aws_security_group.ssh_access.id]
+
+  user_data = templatefile("${path.module}/../cloudinit/postgres-monitor-cloud-init.yaml", {
+    hostname       = var.hostname
+    ssh_public_key = trimspace(file(var.ssh_public_key_path))
+  })
+
+  user_data_replace_on_change = true
+
+  tags = {
+    Name = var.instance_name
+  }
+
+  root_block_device {
+    volume_size = 32
+  }
+}

infra/aggregation_mode/terraform/postgres_monitor/output.tf

@@ -0,0 +1,9 @@
+output "instance_hostname" {
+  description = "Private DNS name of the EC2 instance."
+  value       = aws_instance.postgres_monitor.private_dns
+}
+
+output "public_ip" {
+  description = "Public IP address of the EC2 instance."
+  value       = aws_instance.postgres_monitor.public_ip
+}

infra/aggregation_mode/terraform/postgres_monitor/variables.tf

@@ -0,0 +1,29 @@
+variable "ssh_key_name" {
+  description = "The name of the SSH key pair to use for the EC2 instance."
+  type        = string
+  default     = "postgres-monitor-key"
+}
+
+variable "ssh_public_key_path" {
+  description = "Path to the SSH public key file to upload to AWS."
+  type        = string
+  default     = "~/.ssh/aws.pub"
+}
+
+variable "instance_name" {
+  description = "Value of the EC2 instance's Name tag."
+  type        = string
+  default     = "postgres-monitor"
+}
+
+variable "instance_type" {
+  description = "The EC2 instance's type."
+  type        = string
+  default     = "t2.micro"
+}
+
+variable "hostname" {
+  description = "The hostname to set for the EC2 instance."
+  type        = string
+  default     = "postgres-monitor"
+}

infra/aggregation_mode/terraform/postgres_primary/main.tf

@@ -0,0 +1,49 @@
+terraform {
+  required_providers {
+    scaleway = {
+      source = "scaleway/scaleway"
+    }
+  }
+}
+
+# Get available bare metal offer
+data "scaleway_baremetal_offer" "offer" {
+  zone = var.zone
+  name = var.offer_name
+  subscription_period = "hourly"
+}
+
+# Get Debian 12 OS
+data "scaleway_baremetal_os" "debian12" {
+#   name    = "Debian"
+#   version = "12"
+  os_id = "83640d93-a0b8-45ad-9c9f-30cae48380a4"
+}
+
+# Upload SSH key
+resource "scaleway_iam_ssh_key" "main" {
+  name       = var.ssh_key_name
+  public_key = file(var.ssh_public_key_path)
+}
+
+# Create bare metal server with hourly billing
+resource "scaleway_baremetal_server" "postgres_primary" {
+  name        = var.server_name
+  offer       = data.scaleway_baremetal_offer.offer.offer_id
+  zone        = var.zone
+  description = var.description
+
+  # Install OS
+  os = data.scaleway_baremetal_os.debian12.os_id
+
+  # Attach SSH key
+  ssh_key_ids = [scaleway_iam_ssh_key.main.id]
+
+  # Cloud-init configuration
+#   cloud_init = templatefile("${path.module}/../cloudinit/scaleway-cloud-init.yaml", {
+#     hostname       = var.hostname
+#     ssh_public_key = trimspace(file(var.ssh_public_key_path))
+#   })
+
+  tags = var.tags
+}

infra/aggregation_mode/terraform/postgres_primary/variables.tf

@@ -0,0 +1,47 @@
+variable "zone" {
+  description = "Scaleway zone"
+  type        = string
+  default     = "fr-par-2"
+}
+
+variable "offer_name" {
+  description = "Name of the bare metal server offer"
+  type        = string
+  default     = "EM-A116X-SSD"
+}
+
+variable "server_name" {
+  description = "Name of the bare metal server"
+  type        = string
+  default     = "postgres-primary"
+}
+
+variable "hostname" {
+  description = "Hostname for the server"
+  type        = string
+  default     = "postgres-primary"
+}
+
+variable "description" {
+  description = "Description of the server"
+  type        = string
+  default     = "PostgreSQL primary server"
+}
+
+variable "ssh_key_name" {
+  description = "Name for the SSH key in Scaleway"
+  type        = string
+  default     = "postgres-primary-key"
+}
+
+variable "ssh_public_key_path" {
+  description = "Path to the SSH public key file"
+  type        = string
+  default     = "~/.ssh/scaleway.pem.pub"
+}
+
+variable "tags" {
+  description = "Tags to apply to the server"
+  type        = list(string)
+  default     = ["postgres", "primary"]
+}

infra/aggregation_mode/terraform/terraform.tf

@@ -0,0 +1,14 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = "~> 5.92"
+    }
+    scaleway = {
+      source = "scaleway/scaleway"
+      version = "2.64.0"
+    }
+  }
+
+  required_version = ">= 1.2"
+}